package exampleSupport {
	import com.transmote.flar.marker.FLARMarker;
	
	import flash.display.Shape;
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.geom.Point;
	
	import org.libspark.flartoolkit.core.types.FLARDoublePoint2d;
	
	/**
	 * simple class to draw outlines around detected markers.
	 * 
	 * @author	Eric Socolofsky
	 * @url		http://transmote.com/flar
	 */
	public class MarkerOutliner extends Sprite {
		private var slate_corners:Shape;
		private var slate_vector3D:Shape;
		
		public function MarkerOutliner () {
			this.addEventListener(Event.ENTER_FRAME, this.onEnterFrame);
			this.slate_corners = new Shape();
			this.slate_vector3D = new Shape();
			this.addChild(this.slate_corners);
			this.addChild(this.slate_vector3D);
		}
		
		public function drawOutlines (marker:FLARMarker, thickness:Number, color:Number) :void {
			this.drawCornersOutline(marker, thickness, color);
		}
		
		/**
		 * draw marker outline using the four corners of the detected marker.
		 */
		public function drawCornersOutline (marker:FLARMarker, thickness:Number, color:Number) :void {
			this.slate_corners.graphics.lineStyle(thickness, color);
			var corners:Vector.<Point> = marker.corners;
			var vertex:Point = corners[0];
			this.slate_corners.graphics.moveTo(vertex.x, vertex.y);
			for (var i:uint=1; i<corners.length; i++) {
				vertex = corners[i];
				this.slate_corners.graphics.lineTo(vertex.x, vertex.y)
			}
			vertex = corners[0];
			this.slate_corners.graphics.lineTo(vertex.x, vertex.y);
		}
		
		/**
		 * draw marker outline using x, y, and rotationZ from FLARMarkerOutline.vector3D.
		 * BUG: x and y coords are off for some reason;
		 * 		the amount they're off is somehow related to the z coord.
		 * 		a z coord of ~680 gives the most accurate x,y coordinate reporting.
		 * 		the greater z is than 680, the greater the positive error in x,y coords (towards edges);
		 * 		the lesser z is than 680, the greater the negative error in x,y coords (towards center).
		 */
		public function drawOutlineVector3D (marker:FLARMarker) :void {
			var BASE_Z:Number = 120;
			var BASE_SIZE:Number = Math.min(this.stage.stageWidth, this.stage.stageHeight);
			var size:Number = 80;//(BASE_Z / marker.vector3D.z) * BASE_SIZE;
			
			this.slate_vector3D.x = marker.vector3D.x + 0.5*this.stage.stageWidth;
			this.slate_vector3D.y = marker.vector3D.y + 0.5*this.stage.stageHeight;
			this.slate_vector3D.rotation = marker.vector3D.w;
			
			this.slate_vector3D.graphics.lineStyle(1, 0x00FF00);
			this.slate_vector3D.graphics.drawRect(-0.5*size, -0.5*size, size, size);
			
//			trace("("+marker.vector3D.x+","+marker.vector3D.y+","+marker.vector3D.z+","+marker.vector3D.w+")");
		}
		
		private function onEnterFrame (evt:Event) :void {
			this.slate_corners.graphics.clear();
			this.slate_vector3D.graphics.clear();
		}
	}
}